Просмотр исходного текста страницы Работа с хранилищем значений в 1Cv8

[[Категория:Программирование в 1Cv8]]
{| align=right
| __TOC__
|}
==В хранилище значения можно сохранить почти любую информацию, например,==

===... картинки (фотки):===

<source lang=1c>
ТекИзображение.Объект = СпрТкани.Ссылка;
ТекИзображение.ВидДанных = Перечисления.ВидыДополнительнойИнформацииОбъектов.Изображение;
Хранилище = Новый ХранилищеЗначения(НоваяКартинка, Новый СжатиеДанных());
ТекИзображение.Хранилище = Хранилище.Получить();

// в этом месте он все выводит ...
ЭлементыФормы.ПолеКартинки1.Картинка = Хранилище.Получить();
ТекИзображение.Записать();
</source>

===...табличный документ:===

<source lang=1c>
Процедура СохранитьВХранилищеНажатие(Элемент)
    ТабДок=Новый ТабличныйДокумент;    
    ТабДок.Вывести(ЭлементыФормы.ПолеТабличногоДокумента1);
    Хранилище=Новый ХранилищеЗначения(ТабДок);
    Записать();
КонецПроцедуры

Процедура ВосстановитьИзХранилищаНажатие(Элемент)
    ТабДок=Хранилище.Получить();
    Если ТабДок<>Неопределено Тогда
        ЭлементыФормы.ПолеТабличногоДокумента1.Вывести(ТабДок);
    КонецЕсли;
КонецПроцедуры
</source>

===... произвольные файлы (двоичные данные):===

<source lang=1c>
ХЗ = Новый ХранилищеЗначения(Новый ДвоичныеДанные(файл));
</source>

Восьмерка поддерживает сжатие данных, помещаемых в хранилище:

<source lang=1c>
ХЗ = Новый ХранилищеЗначения(Новый ДвоичныеДанные(файл),Новый СжатиеДанных(9));
</source>

===... внешние обработки и отчеты:===

<source lang=1c>
Процедура ЗагрузитьОбработкуВХранилище(РеквизитТипХранилище)
   СтепеньСжатия = Новый СжатиеДанных(9); //9 максимум   
   РеквизитТипХранилище = Новый ХранилищеЗначения(Новый ДвоичныеДанные("c:\отчеты\отчет.epf", СтепеньСжатия));
КонецПроцедуры
  
Процедура ЗапуститьОбработкуИзХранилища(РеквизитТипХранилище)
   ИмяВременногоФайла = КаталогВременныхФайлов()+"отчет.epf";
   ДвоичныеДанные = РеквизитТипХранилище.Получить();
   ДвоичныеДанные.Записать(ИмяВременногоФайла);
   ВнешняяОбработка = ВнешниеОбработки.Создать(ИмяВременногоФайла);
   ВнешняяОбработка.ПолучитьФорму().Открыть();
КонецПроцедуры
</source>

===Работа с хранилищем===

Если это были ДвоичныеДанные, то их можно восстановить из хранилища значения методом Получить и записать в файл методом Записать().

<source lang=1c>
Если ТипЗнч(Хранилище) <> Тип("ДвоичныеДанные") Тогда
    ДвоичныеДанные = Хранилище.Получить();
Иначе
    ДвоичныеДанные = Хранилище;
КонецЕсли; 
ДвоичныеДанные.Записать(ИмяФайла);
</source>

Если это был, например, Word-документ (doc-файл, или другой файл зарегистрированного типа), то его можно открыть так:

<source lang=1c>
ЗапуститьПриложение(ИмяФайла);
</source>

Чтобы очистить поле типа Хранилище значения, нужно присвоить ему Неопределено:

<source lang=1c>
РеквизитХранилище = Неопределено;
</source>

==Работа с файлами и картинками во встроенном языке 1С:Предприятия 8==
===Назначение===

В управляемом приложении реализован новый механизм работы с файлами. Он обеспечивает обмен файлами между информационной базой и клиентским приложением. Особенностью данного механизма является то, что он ориентирован на использование в тонком клиенте и Веб-клиенте и разработан с учетом ограничений на работу с файлами, накладываемыми веб-браузерами.

Механизм представляет собой набор методов, с помощью которых можно поместить данные, хранящиеся локально у пользователя, во временное хранилище информационной базы, перенести эту информацию из временного хранилища в базу данных и получить ее обратно на компьютер пользователя. Наиболее распространенные прикладные задачи, решаемые этим механизмом, – это хранение сопроводительной информации, например, изображений товаров, связанных с договорами документов и т. п.

===Область действия методов===
====Временное хранилище====

Временное хранилище — это специализированная область информационной базы, в которую могут быть помещены двоичные данные. Основное назначение – это временное хранение информации при клиент-серверном взаимодействии до ее переноса в базу данных.

Необходимость во временном хранилище возникает из-за того, то в модели работы веб-браузера требуется передать выбранный пользователем файл непосредственно на сервер без возможности его хранения на клиенте. При передаче файла он помещается во временное хранилище и уже потом может быть использован при записи объекта в базу данных.

Наиболее типичная решаемая временным хранилищем прикладная задача – обеспечение доступа к файлам или картинкам до того, как объект будет записан в информационную базу, например, в форме элемента.

Файл или двоичные данные, помещенные в хранилище, идентифицируются уникальным адресом, который в дальнейшем можно использовать в операциях записи, чтения или удаления. Этот адрес выдают методы записи файла во временное хранилище. Отдельный метод во встроенном языке позволяет определить, является ли переданный адрес адресом, указывающим на данные во временном хранилище.

====Информационная база====

Механизм позволяет получить доступ к двоичным данным, хранящимся в реквизитах типа ХранилищеЗначений.

Как и в случае временного хранилища, доступ к информации возможен через специальный адрес. Получить его можно через специальный метод, передав ссылку на объект или ключ записи регистра сведений, и имя реквизита. В случае табличной части дополнительно требуется передать и индекс строки табличной части.

Методы работы с файлами имеют ограничение при работе с реквизитами информационной базы. Для них, в отличие от временного хранилища, доступно только чтение информации, но не ее запись или удаление.
===Описание методов работы с файлами===
====Сохранение данных во временное хранилище====

Наиболее типичный сценарий использования данного механизма предусматривает первоначальное размещение данных пользователя во временное хранилище. Для этого предназначены два метода: ПоместитьФайл() и ПоместитьФайлВоВременноеХранилище().

Первый метод, ПоместитьФайл(), помещает файл из локальной файловой системы во временное хранилище. Метод может принимать целевой адрес в хранилище. Если же он не определен или является пустой строкой, то будет создан новый файл и метод вернет его адрес через соответствующий параметр.

Если параметр, определяющий интерактивный режим работы, равен Истина, то метод отобразит стандартное диалоговое окно выбора файла, в котором можно выбрать файл для помещения в хранилище. В этом случае метод также вернет адрес выбранного файла.

Как результат метод возвращает Ложь, если пользователь в интерактивном режиме отказался от совершения операции в диалоге выбора файла. Метод доступен только на клиенте.

Второй метод, ПоместитьФайлВоВременноеХранилище(), схож с предыдущим, за исключением того, что он доступен на сервере, а данные для записи во временное хранилище представляются не в виде пути в файловой системе, а в виде переменной типа ДвоичныеДанные. Точно так же, если не указан целевой адрес, создается новый файл в хранилище. Его адрес возвращается как результат функции.
====Получение файла из временного хранилища====

При записи объекта в информационную базу может понадобиться извлечь данные из временного хранилища и поместить их, например, в реквизит. Для этого есть соответствующий серверный метод — ПолучитьФайлИзВременногоХранилища(). Этот метод извлекает данные из временного хранилища и возвращает их как результат. Для этого необходимо указать адрес во временном хранилище. Этот адрес возвращают вышеописанные методы ПоместитьФайл() и ПоместитьФайлВоВременноеХранилище() в случае их успешного выполнения.
====Удаление файла из временного хранилища====

После того, как данные сохранены в реквизите, файл во временном хранилище можно удалить. Для этого есть метод УдалитьФайлИзВременногоХранилища(), который удаляет файл из временного хранилища. Метод принимает в параметре адрес файла во временном хранилище. Доступен на сервере.
====Проверка адреса на принадлежность временному хранилищу====

Адрес файла может указывать как на временное хранилище, так и на реквизит в информационной базе. Для проверки его типа существует метод ЭтоАдресВременногоХранилища().

Он проверяет, что переданный адрес является адресом, указывающим на хранилище. Возвращает Истина, если адрес указывает на временное хранилище. Метод доступен на сервере.
====Получение адреса реквизита====

После того, как данные помещены в реквизит в информационной базе, может потребоваться получить доступ к ним с помощью файловых методов.

Но прежде чем получить данные, например из реквизита, необходимо получить адрес этого реквизита. Для этого существует метод ПолучитьАдресФайлаВИнформационнойБазе().

Его назначение – вернуть адрес файла в информационной базе по исходным параметрам. Для этого необходимо передать ключ объекта (это может быть как ссылка на объект, так и ключ записи регистра сведений) и имя реквизита. Если нужно получить адрес файла, хранимого в реквизите табличной части, до имени реквизита в параметре, задающем имя реквизита, необходимо добавить имя табличной части и точку «.». Метод доступен как на клиенте, так и на сервере.
====Получение файла из информационной базы====

Метод ПолучитьФайл() получает файл из информационной базы и сохраняет его в локальную файловую систему пользователя. Первый параметр определяет адрес файла в реквизите или во временном хранилище файлов. Второй параметр определяет целевое расположение полученного файла. В не интерактивном режиме необходимо указать путь. В интерактивном режиме параметр является опциональным.

По умолчанию метод исполняется в интерактивном режиме, то есть последний параметр равен Истина. Это значит, что выдается диалоговое окно, в котором можно указать действие с полученным файлом: запустить его или сохранить по указанному пользователем расположению. Если активен интерактивный режим, а параметр Целевой путь к файлу на диске не указан, то операция открытия файла не доступна. Возвращает булевское значение. Ложь означает, что пользователь выбрал отмену операции в диалоговом окне сохранения файлов в интерактивном режиме.
====Пример использования файловых методов====

<source lang=1c>
// Получение в интерактивном режиме файла с диска
// и помещение его во временное хранилище
&НаКлиенте
Процедура ВыбратьФайлСДискаИЗаписать()
    Перем ВыбранноеИмя;
    Перем АдресВременногоХранилища;
    Если ПоместитьФайл(АдресВременногоХранилища, ВыбранноеИмя, Истина) Тогда
       Объект.ИмяФайла = ВыбранноеИмя;
       ПоместитьФайлОбъекта(АдресВременногоХранилища);
    КонецЕсли;
КонецПроцедуры

// Копирование файла из временного хранилища в реквизит
// справочника, запись объекта,удаление файла из временного
// хранилища
&НаСервере
Процедура ПоместитьФайлОбъекта(АдресВременногоХранилища)
    ЭлементСправочника = РеквизитФормыВЗначение("Объект");
    ДвоичныеДанные =  ПолучитьФайлИзВременногоХранилища(АдресВременногоХранилища);
    ЭлементСправочника.ДанныеФайла = Новый ХранилищеЗначения(ДвоичныеДанные);
    ФайлПутьНаДиске = Новый Файл(ЭлементСправочника.ИмяФайла);
    ЭлементСправочника.ИмяФайла = ФайлПутьНаДиске.Имя;
    ЭлементСправочника.Записать();
    Модифицированность = Ложь;
    УдалитьФайлИзВременногоХранилища(АдресВременногоХранилища);
    ЗначениеВРеквизитФормы(ЭлементСправочника, "Объект");
КонецПроцедуры
 
// Считывание файла из реквизита и сохранение его
// на локальном диске в интерактивном режиме
&НаКлиенте
Процедура ПрочитатьФайлИСохранитьНаДиск()
    Адрес =
      ПолучитьАдресФайлаВИнформационнойБазе(Объект.Ссылка,
                                              "ДанныеФайла");
    ПолучитьФайл(Адрес, Объект.ИмяФайла, Истина);
КонецПроцедуры
</source>

====Поддержка адресов в поле картинки====

Элемент управления Поле картинки поддерживает отображение картинки, заданной адресом файла во временном хранилище или в базе данных.

Для этого в свойстве Данные элемента формы необходимо задать реквизит строкового типа. Значение этого реквизита и будет интерпретироваться как адрес картинки.

[Image]

Пример
<source lang=1c>
// Привязка поля картинки к адресу картинки во временном
// хранилище. АдресКартинки реквизит формы строкового типа

ПоместитьФайл(АдресКартинки, ,Истина)

Картинка.Данные = АдресКартинки
</source>

===Ограничения при работе с Веб-клиентом===

Работа описываемого механизма при использовании Веб-клиента имеет некоторые ограничения. Эти ограничения связаны с особенностями модели безопасности браузера. Так, например, клиент самостоятельно не может сохранить файл в локальную файловую систему, то есть доступен только интерактивный вариант клиентских методов ПоместитьФайл() и ПолучитьФайл(). При попытке использовать не интерактивный режим генерируется исключение. Диалоговые окна, отображаемые в интерактивном режиме, специфичны для конкретного типа браузера.


==Особенности при работе с ХранилищемЗначений на Клиенте==

'''Проблема:'''

Когда у Документа в табличной части есть реквизит типа ХранилищеЗначений, то тормозит открытие формы документа, если в этом реквизите записаны данные большого размера. 

'''Предполагаемая причина:'''

Возможно, при открытии формы, на клиент передается не ссылка на данные находящиеся в ХранилищеЗначений, а сами данные.


'''Решение'''
* В свойствах табличного реквизита формы есть флаг "Использовать всегда". Если он установлен, то содержимое поля всегда передается между сервером и клиентом - например, при открытии формы. Этот флаг надо отключить, но при этом нужно учесть это в коде, так как по умолчанию значения этого поля на клиенте не будет. Пример можно посмотреть в 1С:Архив.


Ещё лучше использовать '''временное хранилище''' для передачи файлов между клиентом и сервером.