Особенности создания отчетов (1Cv8)

Материал из КинтВики
Перейти к: навигация, поиск

Содержание

Особенности создания отчетов в 1С v8 в режиме толстого клиента

Как сделать выбор варианта?

  • На панель отчета помещаем кнопку "ВыбратьВариант"
  • На форму помещаем поле "НаДату"

Пример кода:

Процедура ДействияФормыВыборВарианта(Кнопка)
	макет = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
	спВарианты = Новый СписокЗначений;
	Для каждого вариант из макет.ВариантыНастроек Цикл
		спВарианты.Добавить(вариант.Настройки, вариант.Представление);
	КонецЦикла;
	
	выбор = спВарианты.ВыбратьЭлемент();
	Если выбор = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	КомпоновщикНастроек.ЗагрузитьНастройки(выбор.Значение);
	
	Сформировать();
КонецПроцедуры

Процедура НаДатуПриИзменении(Элемент)
	Сформировать();
КонецПроцедуры

Процедура Сформировать()
	ЭлементыФормы.Результат.Очистить();
	КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("Период", НаДату);
	СкомпоноватьРезультат(ЭлементыФормы.Результат);
КонецПроцедуры

Процедура ПриОткрытии()
	НаДату = ТекущаяДата();
	Сформировать();
КонецПроцедуры


Особенности создания отчетов через СКД

Поэтапное создание отчета

  1. Создать Отчет в узле Отчетов
  2. Создать Макет в отчете, тип которого - Схема компоновки данных
  3. В свойствах отчета установить: Основная схема компоновки данных = Созданный Макет
  4. В свойствах отчета установите подсистему, которой он принадлежит (отчет в Предприятии будет выведен в верхней навигационной панели)
  5. Создать запрос в Макете (пункт: Добавить набор данных - Запрос)
  6. В закладке Параметры у Макета необходимо убрать галочки у всех строк в колонке ОграничениеДоступности - т.е. все параметры будут доступны для редактирования пользователю
  7. В закладке Настройки у Макета необходимо в окне, где выводится узел Отчет, создать новую группировку без указания поля группировки - будет создана детальная строка
  8. В закладке Настройки у Макета, в окне где выводится дополнительный набор закладок, выбрать доп. закладку Параметры - пометить все параметры галочкой и на каждом параметре нажать кнопку Свойства элемента пользовательских настроек, откроется окно настройки параметра, где необходимо поставить галочку - Включать параметр в пользовательские настройки
  9. В закладке Настройки у Макета, в окне где выводится дополнительный набор закладок, выбрать доп. закладку ВыбранныеПоля - там необходимо добавить колонки которые будут выводиться в отчете
  10. Запускайте Предприятие, открывайте отчет, устанавливайте значения параметров, Сформировать (проверьте что выбран Основной вариант формирования отчета)

Как добавить нередактируемый пользователем параметр?

Например, нам нужно установить параметр запроса "Информационная база"

  • В форме макета компоновки на закладке Параметры у нужного параметра снять флаги "Включать в доступные поля" и "Ограничение доступности"

Особенности создания отчетов 1Cv8-1.png

  • В форме макета компоновки на закладке Настройка на подзакладке (внизу) Параметры у нужного параметра снять флаг, открыть свойства (кнопка с гаечным ключом), на этой форме:
    • Снять флаг "Включать в пользовательские настройки"
    • Режим редактирования установить "Недоступный"

Особенности создания отчетов 1Cv8-2.png


Особенности создания отчетов 1Cv8-3.png


  • В модуле формы отчета в обработчике события "ПриЗагрузкеВариантаНаСервере" (можно и ПриОткрытии, но НЕ ПриСозданииНаСервере, т.к. она выполняется ДО загрузки настроек отчета и настройки будут перезаписаны) программно установить параметр:
&НаСервере
Процедура ПриЗагрузкеВариантаНаСервере(Настройки)

	НаименованиеТекущегоВарианта = ПредставлениеТекущегоВарианта;
	
//Установка параметра
	Настройки = Отчет.КомпоновщикНастроек.Настройки;
	Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ИнформационнаяБаза", Отчет.ИнформационнаяБаза);
КонецПроцедуры

Как задать варианты отчета?

  • В форме макета компоновки на закладке Настройки в поле слева можно создать необходимые варианты отчета

Как задать группировки?

  • В форме макета компоновки на закладке Настройки в поле справа вверху можно создать необходимые группировки

Как программно вывести отчет?

В модуле формы:

&НаКлиенте
Процедура СформироватьОтчетВыполнить()
    ЭтаФорма.СкомпоноватьРезультат();
КонецПроцедуры

Как тестировать отчет?

Нужно выполнить:

  • Сформировать ситуацию в клиентском тесте - удобнее всего через таблицу ситуации
  • получить форму отчета - форма = ПолучитьФорму("Отчет.ДвижениеПроцесов.Форма.ФормаОтчета");
  • загрузить нужный вариант отчета - установить параметр расширения формы отчета "КлючВарианта" (имя настройки в макете компоновки данных)
  • загрузить нужные настройки отчета - ? заполнить параметр расширения формы отчета "ПользовательскиеНастройки" (тип "ПользовательскиеНастройкиКомпоновкиДанных ") так не получилось, все сложно, см. ниже.
  • открыть форму - форма.Открыть()
  • выполнить формирование - форма.СкомпоноватьРезультат();
  • проверить содержимое табличного документа форма.Результат - хорошо бы иметь функции сравнения с эталонной mxl
  • закрыть форму - форма.Закрыть(); - а может быть, можно и не открывать, надо проверить

см. также

  • описание: меню Справка/Синтакс-помощник/закладка Содержание/Интерфейсные объекты управляемого приложения/Расширения управляемой формы/Расширение управляемой формы для отчета/Параметры формы


При сложных запросах СКД гораздо удобнее тестировать сам запрос отдельно, в серверных тестах, и только после отладки переносить в макет СКД.

  • проще создавать тестовую ситуацию
  • проще проверять результат
  • быстрее

Но хотя бы один простейший клиентский smoke-тест все равно нужен.

Как загрузить нужные настройки отчета?

В документации описано, что есть такой параметр расширения формы отчета "ПользовательскиеНастройки" типа "ПользовательскиеНастройкиКомпоновкиДанных", но там очень сложная объектная структура, не удалось её использовать.

Реально работающая схема:

1. Создаём в отчете параметры

  • Период типа СтандартныйПериод
  • Отбор типа СписокЗначений (лучше было бы Структура, но её нет в списке типов параметров, как и произвольного типа)

2. В процедуру ПолучитьФорму передаем нужные параметры:

период = Новый СтандартныйПериод;
период.Вариант = ВариантСтандартногоПериода.ПроизвольныйПериод;
период.ДатаНачала = текущаяДата;
период.ДатаОкончания = завтрашняяДата;

отбор = Новый СписокЗначений;
отбор.Добавить(Тестирование.ПолучитьОбъект(стСитуация, "БП1"), "БизнесПроцесс"); 

стПараметры = Новый Структура("КлючВарианта,Период,Отбор", "Основной", период, отбор);
// ОткрытьФормуМодально("Отчет.ДвижениеПроцессов.Форма.ФормаОтчета", стПараметры);
форма = ПолучитьФорму("Отчет.ДвижениеПроцессов.Форма.ФормаОтчета", стПараметры);

3. В обработчиках событий формы устанавливаем параметры

&НаСервере
Функция спПолучить(спСписок, представление) Экспорт 
	Для Каждого элемент Из спСписок Цикл
		Если элемент.Представление = представление Тогда
			Возврат элемент.Значение;
		КонецЕсли;
	КонецЦикла;
	Возврат Неопределено;
КонецФункции

&НаСервере
Процедура УстановитьЗначениеПользовательскойНастройки(Настройки, Имя, Значение)
	Для Каждого элемент Из Настройки.Элементы Цикл
		Если ТипЗнч(элемент) = Тип("ЗначениеПараметраНастроекКомпоновкиДанных") Тогда
			Если Строка(элемент.Параметр) = Имя Тогда
				элемент.Значение = Значение;
				элемент.Использование = Истина;
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры

&НаСервере
Процедура УстановитьЗначениеПользовательскогоОтбора(Настройки, Имя, Значение)
	Для Каждого элемент Из Настройки.Элементы Цикл
		Если ТипЗнч(элемент) = Тип("ОтборКомпоновкиДанных") Тогда
			Для Каждого отбор Из элемент.Элементы Цикл
				Если Строка(отбор.ЛевоеЗначение) = Имя Тогда
					отбор.ПравоеЗначение = Значение;
					отбор.Использование = Истина;
				КонецЕсли;
			КонецЦикла;
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры

&НаСервере
Процедура ПриЗагрузкеВариантаНаСервере(Настройки)

	НаименованиеТекущегоВарианта = ПредставлениеТекущегоВарианта;
	
	Настройки = Отчет.КомпоновщикНастроек.Настройки;
	Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ИнформационнаяБаза", Отчет.ИнформационнаяБаза);
	
КонецПроцедуры

&НаСервере
Процедура ПриЗагрузкеПользовательскихНастроекНаСервере(Настройки)
	Настройки = Отчет.КомпоновщикНастроек.ПользовательскиеНастройки;

	Если Параметры.Период.ДатаОкончания <> '00010101' Тогда
		Настройки = Отчет.КомпоновщикНастроек.ПользовательскиеНастройки;
		УстановитьЗначениеПользовательскойНастройки(Настройки, "Период", Параметры.Период);
	КонецЕсли;
	
	ссБизнесПроцесс = спПолучить(Параметры.Отбор, "БизнесПроцесс");
	Если ссБизнесПроцесс <> Неопределено Тогда
		УстановитьЗначениеПользовательскогоОтбора(Настройки, "БизнесПроцесс", ссБизнесПроцесс);
	КонецЕсли;
	
КонецПроцедуры


Замечания:

  • Есть ПараметрыДанных, то есть то что устанавливается в параметры запроса СКД
  • Некоторые из них назначаются в настройке варианта в ПользовательскиеНастройки (в свойтсвах параметра есть флаг "Включить в пользовательские настройки"
  • Даже если при загрузке на сервере в параметры данных загрузить нужные значения, потом открывается форма, в которую автоматически загружаются сохраненные в прошлый раз настройки. Эти настноки при формировании отчета "перебивают" настройки данных
  • В обработчике ПриЗагрузкеПользовательскихНастроекНаСервере передаваемый объект Настройки является копией реальных настроек, поэтому чтобы изменить настройки, которые появятся на форме, надо заполнять объект Отчет.КомпоновщикНастроек.ПользовательскиеНастройки

Как сделать множественные (списком) параметры запроса в СКД?

В запросе нужно использовать выражение "В (&ИмяПараметра)" (см. Логические выражения в языке запросов 1Cv8)

В настройке макета схемы СКД на закладке "Параметры" для этого параметра надо поставить галочку в колонке "Доступен список значений". В этом случае при выборе параметра СКД выдает форму редактирования списка, в которой можно добавить любое значение параметров.


Как сделать отключаемые параметры запроса в СКД?

В запросе СКД надо использовать конструкции, окруженные фигурными скобками "{}".

Если галочка в форме отчета (панель быстрой настройки) у соответствующего параметра снята, то эта конструкция убирается из запроса.

Подробнее см. Расширение языка запросов для системы компоновки данных (1Cv8)

Как сделать отчет с разворотом по колонкам?

Для этого в настройке варианта отчета (редактирование макета компоновки данных, закладка "Настройка", поле справа вверху), нужно в качестве первой группировки добавить "Таблица".

После этого в узле "Таблица" появляются ветки "Строки" и "Колонки", куда и добавляются нужные группировки.

Как настроить формат вывода полей?

В редакторе макета компоновки данных на закладке "Наборы данных" в правой верхней области есть список полей отчёта.

Есть две возможности:

  1. Настроить значение колонки "Выражение представления"
    • здесь можно ввести выражение языка, выдающее нужную строку
    • с полям ресурсов это не работает
  2. Настроить значение колонки "Оформление"
    • в оформлении есть свойство "Формат" - это значение, аналогичное параметру функции языка "Формат", можно задать нужный вид
    • преобразование типов здесь не сделать

Для полей ресурсов можно задавать выражения вычисления (закладка "Ресурсы") - например,

Сумма(Время)/3600.0

для перевода из секунд в часы.

Нужную точность можно задать через "Оформление" поля на закладке "Наборы данных".

Особенности установки параметров системы компоновки данных

Существуют и требуют различной обработки по крайней мере ТРИ вида параметров:

ПараметрыДанных

ПараметрыДанных определяются в запросе (источнике данных) СКД.

Параметры данных передаются в запрос источника данных и определяют извлекаемые данные.

В объекта КомпоновщикНастроек есть специальное свойство для работы с параметрами данных КомпоновщикНастроек.Настройки.ПараметрыДанных

Можно установить вызовом вида

Настройки = Отчет.КомпоновщикНастроек.Настройки;
Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ИнформационнаяБаза", Отчет.ИнформационнаяБаза);

Отбор

Отборы накладываются на полученные данные после извлечения из источника данных.

В объекта КомпоновщикНастроек есть специальное свойство для работы с отборами КомпоновщикНастроек.Настройки.Отбор.

Например:

Настройки = Отчет.КомпоновщикНастроек.Настройки;
Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ИнформационнаяБаза", Отчет.ИнформационнаяБаза);

Для каждого элемент Из Параметры.Отбор Цикл
	ЭлементОтбора = Настройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(элемент.Представление);
	ЭлементОтбора.ПравоеЗначение = элемент.Значение;
КонецЦикла;

ПользовательскиеНастройки

Пользовательские настройки определяют данные, которые пользователь может настроить на форме.

Пользовательские настройки могут отображаются на форме в специальной таблице и могут быть вызваны по кнопке "Настройки" и из меню "Все действия".

Пользовательские настройки связаны с параметрами данных и отборами каким-то достаточно сложным образом, эту связь можно настраивать визуально, но программно с ними работать как-то очень неудобно.

Пока не нашлось ничего лучшего, как устанавливать значения существующей коллекции по индексу, что само собой может отъехать при изменении макета СКД в визуальном редакторе.

Кроме того, если какой-то параметр данных объявлен пользовательским, то программной установки параметра данных (см.выше) недостаточно, восстанавливаемое значение пользовательской настройки перебивает установку параметра данных. Поэтому для таких параметров нет смысла устанавливать параметр данных, нужно сразу устанавливать пользовательскую настройку.

Удобное место для установки нужных значений - обработчик события "ПриЗагрузкеПользовательскихНастроекНаСервере" расширения формы отчёта.

&НаСервере
Процедура ПриЗагрузкеПользовательскихНастроекНаСервере(Настройки)

	Если Параметры.Период.ДатаОкончания <> '00010101' Тогда
		Настройки = Отчет.КомпоновщикНастроек.ПользовательскиеНастройки;
		Настройки.Элементы[0].Значение = Параметры.Период;
	КонецЕсли;

КонецПроцедуры

Использование источника данных в виде объекта

Для использования набора данных типа объект нужно передать внешний источник данных методу Инициализировать объекта "Процессор компоновки данных".

 
ДанныеРасшифровки = Неопределено;

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки);

ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, Новый Структура("Данные", ПолучитьДанныеВнешнегоИсточника()), ДанныеРасшифровки);

Простой пример приложен (для работы примера необходимо наличие справочников "Контрагенты" и "Договоры контрагентов").

Источник: http://partners.v8.1c.ru/forum/thread.jsp?id=496129#496129



Пример: Медиа:OtcetPoDetalam.rar

Язык выражений системы компоновки данных

Использование нестандартных макетов оформления отчета СКД

Кое-как удалось заставить СКД формировать заголовки группировок.

Непонятная на первый взгляд фишка - то, что в настройках группировок нужно задать "Имя" группировки (через контекстное меню - "Установить имя"), а кроме того это имя группировки надо добавлять в "Детальные записи" а не в групприровки..

В общем, темный лес, не для средних умов..

Вывод разрыва страницы при печати через СКД

Просто вставить в макет разрыв страницы ничего не дало - в результат он не попадает.

Поиск дал информацию что это проблема СКД

Ответ 1С:

Лейбович Максим (1С, Москва)

09.02.2009 09:13 Отвечает на: »»»»

653075 Re: разрыв страницы при выводе отчета средствами сиситемы компоновки данных

Такой возможности нет. Аналогичные пожелания зарегистрированы.

Источник: http://partners.v8.1c.ru/forum/thread.jsp?id=642887#642887


Рекомендуют выводить программно через ВывестиГоризонтальныйРазделительСтраниц.

В новой версии 8.2 в модуле объекта отчета есть обработчик события ПриКомпоновкеРезультата. (Приятная особенность - пример в документации 8.2 написан с ошибками и вообще не работает:)

Работающая версия:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	Если ЭтотОбъект.ТекущийВариант <> "ПоОрганизациям" 
		И ЭтотОбъект.ТекущийВариант <> "ОстаткиПоОрганизациям" 
	Тогда
		Возврат;
	КонецЕсли;
	СтандартнаяОбработка = Ложь;
	
	Настройки = КомпоновщикНастроек.ПолучитьНастройки();
	Параметр = Настройки.ПараметрыДанных.Элементы.Найти(Новый ПараметрКомпоновкиДанных("Фирма"));
	Параметр.Использование = Истина;
	Параметр.Значение =  Строка(ПараметрыСеанса.РабочаяФирма.Организация.ФормаСобственности) + " """ + Строка(ПараметрыСеанса.РабочаяФирма.Организация) + """";
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
	МакетКомпоновкиДанных =   КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,,ДанныеРасшифровки);
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	
	ДокументРезультат.ОриентацияСтраницы = ОриентацияСтраницы.Ландшафт;
	ДокументРезультат.АвтоМасштаб = Истина;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	ПроцессорВывода.НачатьВывод();
	Пока Истина Цикл
		ЭлементРезультатаКомпоновкиДанных = ПроцессорКомпоновкиДанных.Следующий();
		Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда
			Прервать;
		КонецЕсли;
		ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);
		Если ЭтотОбъект.ТекущийВариант = "ПоОрганизациям" И ЭлементРезультатаКомпоновкиДанных.Макет = "Макет3" Тогда
			ДокументРезультат.ВывестиГоризонтальныйРазделительСтраниц();
		ИначеЕсли ЭтотОбъект.ТекущийВариант = "ОстаткиПоОрганизациям" И ЭлементРезультатаКомпоновкиДанных.Макет = "Макет3" Тогда
			ДокументРезультат.ВывестиГоризонтальныйРазделительСтраниц();
		КонецЕсли;
	КонецЦикла;
	ПроцессорВывода.ЗакончитьВывод();
	
КонецПроцедуры

--Павел Лазарев 16:02, 7 сентября 2009 (SAMST)

  • В этом примере если НЕ создать объект ДанныеРасшифровки (как и было в документации 1С), то НЕ вызывается меню расшифровки по умолчанию по клику на ячейке.